Sequenzen (sequences); JavaFX 1.0

Arbeiten mit Sequenzen:

   var days = ["Mo", "Mi", "Do", "Sa"];
   println("{days} - {sizeof days}");  // "MoMiDoSa - 4"
 
   // Einen Wert anhängen:
   insert "So" into days;
   println("{days} - {sizeof days}");  // "MoMiDoSaSo - 5"
 
   // Einen Wert einfügen vor:
   insert "Di" before days[1];
   println("{days} - {sizeof days}");  // "MoDiMiDoSaSo - 6"
 
   // Einen Wert einfügen nach:
   insert "Fr" after days[3];
   println("{days} - {sizeof days}");  // "MoDiMiDoFrSaSo - 7"
 
   var week = days;
 
   // Löschen per Item:
   delete "Sa" from days;
   println("{days} - {sizeof days}");  // "MoDiMiDoFrSo - 6"
 
   // Löschen per Index:
   delete days[5];
   println("{days} - {sizeof days}");  // "MoDiMiDoFr - 5"
 
   // Reihenfolge umkehren:
   days = reverse days;
   println("{days} - {sizeof days}");  // "FrDoMiDiMo - 5"
 
   // Teilsequenzen (slices):
   days = days[1..3];
   println("{days} - {sizeof days}");  // "DoMiDi - 3"
 
   // Teilsequenzen (slices):
   days = week[0..<5];  // incl. erstem Index, exclusive zweitem Index
   println("{days} - {sizeof days}");  // "MoDiMiDoFr - 5""
 
   // Teilsequenzen (slices):
   days = week[5..];  // ab Index bis zum Ende
   println("{days} - {sizeof days}");  // "SaSo - 2"
 
   // Teilsequenzen (slices):
   days = week[1..<];  // ab Index bis exclusive Ende
   println("{days} - {sizeof days}");  // "DiMiDoFrSa - 5"
 
   // Alle Elemente löschen:
   delete days;
   println("{days} - {sizeof days}");  // " - 0"
 
   // Schleife über alle Elemente:
   for (e in week)
      println(e);     // Ausgabe in 5 Zeilen: "Di" "Mi" "Do" "Fr" "Sa"

Vergleichen zweier Sequenzen:

if (days == week)
   println("Beide Sequenzen sind gleich lang und enthalten die gleichen Elemente");
else
   println("Die Länge der Sequenzen ist nicht gleich und/oder die Elemente sind unterschiedlich");

Sequenzen mit Zahlen:

var nums = [0..5];
println(nums);  // "[ 0, 1, 2, 3, 4, 5 ]"
 
nums = [1..5 step 2];
println(nums);  // "[ 1, 3, 5 ]"
 
nums = [5..1 step -1];
println(nums);  // "[ 5, 4, 3, 2, 1 ]"